SMESH_MeshEditor.idl

Go to the documentation of this file.

// Copyright (C) 2007-2016  CEA/DEN, EDF R&D, OPEN CASCADE
//
// Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
// CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
//
// This library is free software; you can redistribute it and/or
// modify it under the terms of the GNU Lesser General Public
// License as published by the Free Software Foundation; either
// version 2.1 of the License, or (at your option) any later version.
//
// This library is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
// Lesser General Public License for more details.
//
// You should have received a copy of the GNU Lesser General Public
// License along with this library; if not, write to the Free Software
// Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
//
// See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
//
//  File   : SMESH_MeshEditor.idl

#ifndef _SMESH_MESHEDITOR_IDL_
#define _SMESH_MESHEDITOR_IDL_

#include "SMESH_Mesh.idl"
#include "SMESH_Gen.idl"

module SMESH
{
  interface NumericalFunctor;

  enum Bnd_Dimension { BND_2DFROM3D, BND_1DFROM3D, BND_1DFROM2D };


  struct FreeBorder
  {
    SMESH::long_array nodeIDs; // all nodes defining a free border
    // 1st and last node is same in a closed border
  };
  struct FreeBorderPart
  {
    short border; // border index within a sequence<FreeBorder>
    long  node1;  // node index within the border-th FreeBorder
    long  node2;
    long  nodeLast;
  };
  typedef sequence<FreeBorder>       ListOfFreeBorders;
  typedef sequence<FreeBorderPart>   FreeBordersGroup;
  typedef sequence<FreeBordersGroup> ListOfFreeBorderGroups;

  struct CoincidentFreeBorders
  {
    ListOfFreeBorders      borders;          // nodes of all free borders
    ListOfFreeBorderGroups coincidentGroups; // groups of coincident parts of borders
  };


  interface SMESH_MeshEditor
  {
    SMESH_Mesh GetMesh();

    MeshPreviewStruct GetPreviewData() raises (SALOME::SALOME_Exception);

    long_array GetLastCreatedNodes() raises (SALOME::SALOME_Exception);

    long_array GetLastCreatedElems() raises (SALOME::SALOME_Exception);

    void ClearLastCreated() raises (SALOME::SALOME_Exception);

    ComputeError GetLastError() raises (SALOME::SALOME_Exception);

    SMESH_IDSource MakeIDSource(in long_array IDsOfElements, in ElementType type);

    boolean RemoveElements(in long_array IDsOfElements) raises (SALOME::SALOME_Exception);

    boolean RemoveNodes(in long_array IDsOfNodes) raises (SALOME::SALOME_Exception);

    long RemoveOrphanNodes() raises (SALOME::SALOME_Exception);

    long AddNode(in double x, in double y, in double z) raises (SALOME::SALOME_Exception);

    long Add0DElement(in long    IDOfNode,
                      in boolean DuplicateElements) raises (SALOME::SALOME_Exception);

    long AddBall(in long IDOfNode, in double diameter) raises (SALOME::SALOME_Exception);

    long AddEdge(in long_array IDsOfNodes) raises (SALOME::SALOME_Exception);

    long AddFace(in long_array IDsOfNodes) raises (SALOME::SALOME_Exception);

    long AddPolygonalFace(in long_array IdsOfNodes) raises (SALOME::SALOME_Exception);

    long AddQuadPolygonalFace(in long_array IdsOfNodes) raises (SALOME::SALOME_Exception);

    long AddVolume(in long_array IDsOfNodes) raises (SALOME::SALOME_Exception);

    long AddPolyhedralVolume (in long_array IdsOfNodes,
                              in long_array Quantities) raises (SALOME::SALOME_Exception);
    long AddPolyhedralVolumeByFaces (in long_array IdsOfFaces) raises (SALOME::SALOME_Exception);

    SMESH_IDSource Create0DElementsOnAllNodes(in SMESH_IDSource theObject,
                                              in string         theGroupName,
                                              in boolean        theDuplicateElements)
      raises (SALOME::SALOME_Exception);

    void SetNodeOnVertex(in long NodeID, in long VertexID)
      raises (SALOME::SALOME_Exception);
    void SetNodeOnEdge(in long NodeID, in long EdgeID, in double paramOnEdge)
      raises (SALOME::SALOME_Exception);
    void SetNodeOnFace(in long NodeID, in long FaceID, in double u, in double v)
      raises (SALOME::SALOME_Exception);
    void SetNodeInVolume(in long NodeID, in long SolidID)
      raises (SALOME::SALOME_Exception);
    void SetMeshElementOnShape(in long ElementID, in long ShapeID)
      raises (SALOME::SALOME_Exception);


    boolean MoveNode(in long NodeID, in double x, in double y, in double z)
      raises (SALOME::SALOME_Exception);

    boolean InverseDiag(in long NodeID1, in long NodeID2) 
      raises (SALOME::SALOME_Exception);

    boolean DeleteDiag(in long NodeID1, in long NodeID2) 
      raises (SALOME::SALOME_Exception);

    boolean Reorient(in long_array IDsOfElements) 
      raises (SALOME::SALOME_Exception);

    boolean ReorientObject(in SMESH_IDSource theObject) 
      raises (SALOME::SALOME_Exception);
    long Reorient2D(in SMESH_IDSource the2Dgroup,
                    in DirStruct      theDirection,
                    in long           theFace,
                    in PointStruct    thePoint) raises (SALOME::SALOME_Exception);
    long Reorient2DBy3D(in ListOfIDSources faces,
                        in SMESH_IDSource  volumes,
                        in boolean         outsideNormal) raises (SALOME::SALOME_Exception);

    boolean TriToQuad (in long_array       IDsOfElements,
                       in NumericalFunctor Criterion,
                       in double           MaxAngle) raises (SALOME::SALOME_Exception);
    boolean TriToQuadObject (in SMESH_IDSource   theObject,
                             in NumericalFunctor Criterion,
                             in double           MaxAngle) raises (SALOME::SALOME_Exception);

    boolean QuadToTri (in long_array       IDsOfElements,
                       in NumericalFunctor Criterion) raises (SALOME::SALOME_Exception);
    boolean QuadToTriObject (in SMESH_IDSource   theObject,
                             in NumericalFunctor Criterion) raises (SALOME::SALOME_Exception);
    void QuadTo4Tri (in SMESH_IDSource theQuads) raises (SALOME::SALOME_Exception);

    boolean SplitQuad (in long_array IDsOfElements,
                       in boolean    Diag13) raises (SALOME::SALOME_Exception);
    boolean SplitQuadObject (in SMESH_IDSource theObject,
                             in boolean        Diag13) raises (SALOME::SALOME_Exception);

    long BestSplit (in long             IDOfQuad,
                    in NumericalFunctor Criterion) raises (SALOME::SALOME_Exception);

    void SplitVolumesIntoTetra(in SMESH_IDSource elems, in short methodFlags)
      raises (SALOME::SALOME_Exception);

    void SplitHexahedraIntoPrisms(in SMESH_IDSource     elems,
                                  in SMESH::PointStruct startHexPoint,
                                  in SMESH::DirStruct   facetToSplitNormal,
                                  in short              methodFlags,
                                  in boolean            allDomains)
      raises (SALOME::SALOME_Exception);

    void SplitBiQuadraticIntoLinear(in ListOfIDSources elems)
      raises (SALOME::SALOME_Exception);


    enum Smooth_Method { LAPLACIAN_SMOOTH, CENTROIDAL_SMOOTH };

    boolean Smooth(in long_array    IDsOfElements,
                   in long_array    IDsOfFixedNodes,
                   in long          MaxNbOfIterations,
                   in double        MaxAspectRatio,
                   in Smooth_Method Method) raises (SALOME::SALOME_Exception);

    boolean SmoothObject(in SMESH_IDSource  theObject,
                         in long_array      IDsOfFixedNodes,
                         in long            MaxNbOfIterations,
                         in double          MaxAspectRatio,
                         in Smooth_Method   Method) raises (SALOME::SALOME_Exception);

    boolean SmoothParametric(in long_array    IDsOfElements,
                             in long_array    IDsOfFixedNodes,
                             in long          MaxNbOfIterations,
                             in double        MaxAspectRatio,
                             in Smooth_Method Method) raises (SALOME::SALOME_Exception);

    boolean SmoothParametricObject(in SMESH_IDSource  theObject,
                                   in long_array      IDsOfFixedNodes,
                                   in long            MaxNbOfIterations,
                                   in double          MaxAspectRatio,
                                   in Smooth_Method   Method) raises (SALOME::SALOME_Exception);

    void ConvertToQuadratic(in boolean theForce3d) 
      raises (SALOME::SALOME_Exception);
    void ConvertToQuadraticObject(in boolean        theForce3d, 
                                  in SMESH_IDSource theObject) 
      raises (SALOME::SALOME_Exception);
    
    boolean ConvertFromQuadratic() 
      raises (SALOME::SALOME_Exception);
    void    ConvertFromQuadraticObject(in SMESH_IDSource theObject)
      raises (SALOME::SALOME_Exception);

    void ConvertToBiQuadratic(in boolean        theForce3d,
                              in SMESH_IDSource theObject)
      raises (SALOME::SALOME_Exception);

    void RenumberNodes() raises (SALOME::SALOME_Exception);

    void RenumberElements() raises (SALOME::SALOME_Exception);

    ListOfGroups RotationSweepObjects(in ListOfIDSources Nodes,
                                      in ListOfIDSources Edges,
                                      in ListOfIDSources Faces,
                                      in AxisStruct      Axis,
                                      in double          AngleInRadians,
                                      in long            NbOfSteps,
                                      in double          Tolerance,
                                      in boolean         ToMakeGroups)
      raises (SALOME::SALOME_Exception);

    ListOfGroups ExtrusionSweepObjects(in ListOfIDSources nodes,
                                       in ListOfIDSources edges,
                                       in ListOfIDSources faces,
                                       in DirStruct       stepVector,
                                       in long            nbOfSteps,
                                       in double_array    scaleFactors,
                                       in boolean         linearVariation,
                                       in double_array    basePoint,
                                       in boolean         toMakeGroups)
      raises (SALOME::SALOME_Exception);

    ListOfGroups ExtrusionByNormal(in ListOfIDSources theObjects,
                                   in double          stepSize,
                                   in long            nbOfSteps,
                                   in boolean         byAverageNormal,
                                   in boolean         useInputElemsOnly,
                                   in boolean         makeGroups,
                                   in short           dim)
      raises (SALOME::SALOME_Exception);

    ListOfGroups AdvancedExtrusion(in long_array IDsOfElements,
                                   in DirStruct  StepVector,
                                   in long       NbOfSteps,
                                   in long       ExtrFlags,
                                   in double     SewTolerance,
                                   in boolean    ToMakeGroups)
      raises (SALOME::SALOME_Exception);

    enum Extrusion_Error {
      EXTR_OK,
      EXTR_NO_ELEMENTS,
      EXTR_PATH_NOT_EDGE,
      EXTR_BAD_PATH_SHAPE,
      EXTR_BAD_STARTING_NODE,
      EXTR_BAD_ANGLES_NUMBER,
      EXTR_CANT_GET_TANGENT
    };

    ListOfGroups ExtrusionAlongPathObjects(in ListOfIDSources Nodes,
                                           in ListOfIDSources Edges,
                                           in ListOfIDSources Faces,
                                           in SMESH_IDSource    Path,
                                           in GEOM::GEOM_Object PathShape,
                                           in long              NodeStart,
                                           in boolean           HasAngles,
                                           in double_array      Angles,
                                           in boolean           LinearVariation,
                                           in boolean           HasRefPoint,
                                           in PointStruct       RefPoint,
                                           in boolean           MakeGroups,
                                           out Extrusion_Error  Error)
      raises (SALOME::SALOME_Exception);

    double_array LinearAnglesVariation(in SMESH_Mesh        PathMesh,
                                       in GEOM::GEOM_Object PathShape,
                                       in double_array      Angles);

    enum MirrorType { POINT, AXIS, PLANE };

    void Mirror (in long_array IDsOfElements,
                 in AxisStruct Mirror,
                 in MirrorType Type,
                 in boolean    Copy) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups MirrorMakeGroups (in long_array IDsOfElements,
                                   in AxisStruct Mirror,
                                   in MirrorType Type) 
      raises (SALOME::SALOME_Exception);
    SMESH_Mesh MirrorMakeMesh (in long_array IDsOfElements,
                               in AxisStruct Mirror,
                               in MirrorType Type,
                               in boolean    CopyGroups,
                               in string     MeshName) 
      raises (SALOME::SALOME_Exception);

    void MirrorObject (in SMESH_IDSource theObject,
                       in AxisStruct     Mirror,
                       in MirrorType     Type,
                       in boolean        Copy) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups MirrorObjectMakeGroups (in SMESH_IDSource theObject,
                                         in AxisStruct     Mirror,
                                         in MirrorType     Type) 
      raises (SALOME::SALOME_Exception);
    SMESH_Mesh MirrorObjectMakeMesh (in SMESH_IDSource theObject,
                                     in AxisStruct     Mirror,
                                     in MirrorType     Type,
                                     in boolean        CopyGroups,
                                     in string         MeshName) 
      raises (SALOME::SALOME_Exception);

    void Translate (in long_array IDsOfElements,
                    in DirStruct  Vector,
                    in boolean    Copy) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups TranslateMakeGroups (in long_array IDsOfElements,
                                      in DirStruct  Vector) 
      raises (SALOME::SALOME_Exception);
    SMESH_Mesh TranslateMakeMesh (in long_array IDsOfElements,
                                  in DirStruct  Vector,
                                  in boolean    CopyGroups,
                                  in string     MeshName) 
      raises (SALOME::SALOME_Exception);

    void TranslateObject (in SMESH_IDSource theObject,
                          in DirStruct      Vector,
                          in boolean        Copy) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups TranslateObjectMakeGroups (in SMESH_IDSource theObject,
                                            in DirStruct      Vector) 
      raises (SALOME::SALOME_Exception);
    SMESH_Mesh TranslateObjectMakeMesh (in SMESH_IDSource theObject,
                                        in DirStruct      Vector,
                                        in boolean        CopyGroups,
                                        in string         MeshName) 
      raises (SALOME::SALOME_Exception);

    void Scale (in SMESH_IDSource theObject,
                in PointStruct    thePoint,
                in double_array   theScaleFact,
                in boolean        Copy) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups ScaleMakeGroups (in SMESH_IDSource theObject,
                                  in PointStruct    thePoint,
                                  in double_array   theScaleFact) 
      raises (SALOME::SALOME_Exception);
    SMESH_Mesh ScaleMakeMesh (in SMESH_IDSource theObject,
                              in PointStruct    thePoint,
                              in double_array   theScaleFact,
                              in boolean        CopyGroups,
                              in string         MeshName) 
      raises (SALOME::SALOME_Exception);

    void Rotate (in long_array IDsOfElements,
                 in AxisStruct Axis,
                 in double     AngleInRadians,
                 in boolean    Copy) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups RotateMakeGroups (in long_array IDsOfElements,
                                   in AxisStruct Axis,
                                   in double     AngleInRadians) 
      raises (SALOME::SALOME_Exception);
    SMESH_Mesh RotateMakeMesh (in long_array IDsOfElements,
                               in AxisStruct Axis,
                               in double     AngleInRadians,
                               in boolean    CopyGroups,
                               in string     MeshName)
      raises (SALOME::SALOME_Exception);

    void RotateObject (in SMESH_IDSource theObject,
                       in AxisStruct     Axis,
                       in double         AngleInRadians,
                       in boolean        Copy)
      raises (SALOME::SALOME_Exception);
    ListOfGroups RotateObjectMakeGroups (in SMESH_IDSource theObject,
                                         in AxisStruct     Axis,
                                         in double         AngleInRadians)
      raises (SALOME::SALOME_Exception);
    SMESH_Mesh RotateObjectMakeMesh (in SMESH_IDSource theObject,
                                     in AxisStruct     Axis,
                                     in double         AngleInRadians,
                                     in boolean        CopyGroups,
                                     in string         MeshName)
      raises (SALOME::SALOME_Exception);

    void FindCoincidentNodes (in  double              Tolerance,
                              out array_of_long_array GroupsOfNodes,
                              in  boolean             SeparateCornersAndMedium)
      raises (SALOME::SALOME_Exception);

    void FindCoincidentNodesOnPart (in  SMESH_IDSource      SubMeshOrGroup,
                                    in  double              Tolerance,
                                    out array_of_long_array GroupsOfNodes,
                                    in  boolean             SeparateCornersAndMedium)
      raises (SALOME::SALOME_Exception);

    void FindCoincidentNodesOnPartBut (in  SMESH_IDSource      SubMeshOrGroup,
                                       in  double              Tolerance,
                                       out array_of_long_array GroupsOfNodes,
                                       in  ListOfIDSources     ExceptSubMeshOrGroups,
                                       in  boolean             SeparateCornersAndMedium)
      raises (SALOME::SALOME_Exception);

    void MergeNodes (in array_of_long_array    GroupsOfNodes,
                     in SMESH::ListOfIDSources NodesToKeep,
                     in boolean                AvoidMakingHoles)
      raises (SALOME::SALOME_Exception);

    void FindEqualElements (in  SMESH_IDSource      MeshOrSubMeshOrGroup,
                            out array_of_long_array GroupsOfElementsID) 
      raises (SALOME::SALOME_Exception);

    void MergeElements(in array_of_long_array GroupsOfElementsID) 
      raises (SALOME::SALOME_Exception);

    void MergeEqualElements() 
      raises (SALOME::SALOME_Exception);

    long MoveClosestNodeToPoint(in double x, in double y, in double z, in long nodeID) 
      raises (SALOME::SALOME_Exception);

    long FindNodeClosestTo(in double x, in double y, in double z) 
      raises (SALOME::SALOME_Exception);

    long_array FindElementsByPoint(in double x, in double y, in double z, in ElementType type) 
      raises (SALOME::SALOME_Exception);

    long_array FindAmongElementsByPoint(in SMESH_IDSource elements,
                                        in double x, in double y, in double z, 
                                        in ElementType type) 
      raises (SALOME::SALOME_Exception);

    short GetPointState(in double x, in double y, in double z) 
      raises (SALOME::SALOME_Exception);

    CoincidentFreeBorders FindCoincidentFreeBorders(in double tolerance);

    short SewCoincidentFreeBorders (in CoincidentFreeBorders freeBorders,
                                    in boolean               createPolygons,
                                    in boolean               createPolyedrs)
      raises (SALOME::SALOME_Exception);

    enum Sew_Error {
      SEW_OK,
      SEW_BORDER1_NOT_FOUND,
      SEW_BORDER2_NOT_FOUND,
      SEW_BOTH_BORDERS_NOT_FOUND,
      SEW_BAD_SIDE_NODES,
      SEW_VOLUMES_TO_SPLIT,
      // for SewSideElements() only:
      SEW_DIFF_NB_OF_ELEMENTS,
      SEW_TOPO_DIFF_SETS_OF_ELEMENTS,
      SEW_BAD_SIDE1_NODES,
      SEW_BAD_SIDE2_NODES,
      SEW_INTERNAL_ERROR
    };

    Sew_Error SewFreeBorders (in long FirstNodeID1,
                              in long SecondNodeID1,
                              in long LastNodeID1,
                              in long FirstNodeID2,
                              in long SecondNodeID2,
                              in long LastNodeID2,
                              in boolean CreatePolygons,
                              in boolean CreatePolyedrs) 
      raises (SALOME::SALOME_Exception);

    Sew_Error SewConformFreeBorders (in long FirstNodeID1,
                                     in long SecondNodeID1,
                                     in long LastNodeID1,
                                     in long FirstNodeID2,
                                     in long SecondNodeID2) 
      raises (SALOME::SALOME_Exception);

    Sew_Error SewBorderToSide (in long FirstNodeIDOnFreeBorder,
                               in long SecondNodeIDOnFreeBorder,
                               in long LastNodeIDOnFreeBorder,
                               in long FirstNodeIDOnSide,
                               in long LastNodeIDOnSide,
                               in boolean CreatePolygons,
                               in boolean CreatePolyedrs) 
      raises (SALOME::SALOME_Exception);

    Sew_Error SewSideElements (in long_array IDsOfSide1Elements,
                               in long_array IDsOfSide2Elements,
                               in long       NodeID1OfSide1ToMerge,
                               in long       NodeID1OfSide2ToMerge,
                               in long       NodeID2OfSide1ToMerge,
                               in long       NodeID2OfSide2ToMerge) 
      raises (SALOME::SALOME_Exception);

    boolean ChangeElemNodes(in long ide, in long_array newIDs) 
      raises (SALOME::SALOME_Exception);

    SMESH_Group DoubleElements( in SMESH_IDSource theElements, 
                                in string         theGroupName )
      raises (SALOME::SALOME_Exception);

    boolean DoubleNodes( in long_array theNodes, in long_array theModifiedElems ) 
      raises (SALOME::SALOME_Exception);

    boolean DoubleNode( in long theNodeId, in long_array theModifiedElems ) 
      raises (SALOME::SALOME_Exception);

    boolean DoubleNodeGroup( in SMESH_GroupBase theNodes,
                             in SMESH_GroupBase theModifiedElems ) 
      raises (SALOME::SALOME_Exception);
    SMESH_Group DoubleNodeGroupNew( in SMESH_GroupBase theNodes,
                                    in SMESH_GroupBase theModifiedElems ) 
      raises (SALOME::SALOME_Exception);

    boolean DoubleNodeGroups( in ListOfGroups theNodes,
                              in ListOfGroups theModifiedElems ) 
      raises (SALOME::SALOME_Exception);
    SMESH_Group DoubleNodeGroupsNew( in ListOfGroups theNodes,
                         in ListOfGroups theModifiedElems ) 
      raises (SALOME::SALOME_Exception);

    boolean DoubleNodeElem( in long_array theElems,
                            in long_array theNodesNot,
                            in long_array theAffectedElems ) 
      raises (SALOME::SALOME_Exception);

    boolean DoubleNodeElemInRegion( in long_array theElems,
                                    in long_array theNodesNot,
                                    in GEOM::GEOM_Object theShape ) 
      raises (SALOME::SALOME_Exception);

    boolean DoubleNodeElemGroup( in SMESH_GroupBase theElems,
                                 in SMESH_GroupBase theNodesNot,
                                 in SMESH_GroupBase theAffectedElems ) 
      raises (SALOME::SALOME_Exception);
    SMESH_Group DoubleNodeElemGroupNew( in SMESH_GroupBase theElems,
                                        in SMESH_GroupBase theNodesNot,
                                        in SMESH_GroupBase theAffectedElems ) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups DoubleNodeElemGroup2New( in SMESH_GroupBase theElems,
                                          in SMESH_GroupBase theNodesNot,
                                          in SMESH_GroupBase theAffectedElems,
                                          in boolean         theElemGroupNeeded,
                                          in boolean         theNodeGroupNeeded) 
      raises (SALOME::SALOME_Exception);

    boolean DoubleNodeElemGroupInRegion( in SMESH_GroupBase theElems,
                                         in SMESH_GroupBase theNodesNot,
                                         in GEOM::GEOM_Object theShape ) 
      raises (SALOME::SALOME_Exception);

    boolean DoubleNodeElemGroups( in ListOfGroups theElems,
                                  in ListOfGroups theNodesNot,
                                  in ListOfGroups theAffectedElems ) 
      raises (SALOME::SALOME_Exception);
    SMESH_Group DoubleNodeElemGroupsNew( in ListOfGroups theElems,
                                         in ListOfGroups theNodesNot,
                                         in ListOfGroups theAffectedElems ) 
      raises (SALOME::SALOME_Exception);
    ListOfGroups DoubleNodeElemGroups2New( in ListOfGroups theElems,
                                           in ListOfGroups theNodesNot,
                                           in ListOfGroups theAffectedElems,
                                           in boolean         theElemGroupNeeded,
                                           in boolean         theNodeGroupNeeded ) 
      raises (SALOME::SALOME_Exception);

    boolean DoubleNodeElemGroupsInRegion( in ListOfGroups theElems,
                                          in ListOfGroups theNodesNot,
                                          in GEOM::GEOM_Object theShape )
      raises (SALOME::SALOME_Exception);

    ListOfGroups AffectedElemGroupsInRegion( in ListOfGroups theElems,
                                             in ListOfGroups theNodesNot,
                                             in GEOM::GEOM_Object theShape ) 
      raises (SALOME::SALOME_Exception);

    boolean Make2DMeshFrom3D() raises (SALOME::SALOME_Exception);

    SMESH_Mesh MakeBoundaryMesh(in SMESH_IDSource elements,
                                in Bnd_Dimension  dimension,
                                in string         groupName,
                                in string         meshName,
                                in boolean        toCopyElements,
                                in boolean        toCopyExistingBondary,
                                out SMESH_Group   group) raises (SALOME::SALOME_Exception);
    long MakeBoundaryElements(in Bnd_Dimension   dimension,
                              in string          groupName,
                              in string          meshName,
                              in boolean         toCopyAll,
                              in ListOfIDSources groups,
                              out SMESH_Mesh     mesh,
                              out SMESH_Group    group) raises (SALOME::SALOME_Exception);

    boolean DoubleNodesOnGroupBoundaries( in ListOfGroups theDomains,
                                          in boolean      createJointElems,
                                          in boolean      onAllBoundaries) 
      raises (SALOME::SALOME_Exception);

    boolean CreateFlatElementsOnFacesGroups( in ListOfGroups theGroupsOfFaces ) 
      raises (SALOME::SALOME_Exception); 

    void CreateHoleSkin(in double radius,
                        in GEOM::GEOM_Object theShape,
                        in string groupName,
                        in double_array theNodesCoords,
                        out array_of_long_array GroupsOfNodes) 
      raises (SALOME::SALOME_Exception);
  };
};

#endif